.子程序 _启动子程序, 整数型, , 请在本子程序中放置易模块初始化代码

载入 (窗口1, , 假)

_临时子程序 ()  ' 在初始化代码执行完毕后调用测试代码

返回 (0)  ' 可以根据您的需要返回任意数值

.子程序 _临时子程序

' 本名称子程序用作测试程序用，仅在开发及调试环境中有效，编译发布程序前将被系统自动清空，请将所有用作测试的临时代码放在本子程序中。 ***注意不要修改本子程序的名称、参数及返回值类型。

.子程序 取后缀名图标_SHG, 字节集, 公开, 取自 凌晨孤星 开源代码.API  返回png图片

.参数 参_后缀, 文本型, , .txt(取快捷方式图标，请填写全路径)

.局部变量 文件信息, SHFILEINFO

SHGetFileInfo (参_后缀, 128, 文件信息, 348, 272)

返回 (转换图标_从句柄 (文件信息.hIcon))

.子程序 取后缀名图标_注册表, 字节集, 公开, 通过注册表取本机后缀图标  返回png图片

.参数 参_后缀, 文本型, , .txt

.参数 是否小图标, 逻辑型, 可空, 默认为假，取大图标。  大图标(32*32)  小图标(16*16)

.局部变量 Text, 文本型

.局部变量 Text_注册表, 文本型

.局部变量 局_Path, 文本型

.局部变量 局_索引, 整数型

.局部变量 hIco32, 整数型

.局部变量 hIco16, 整数型

.局部变量 a, 整数型

Text ＝ 取文本右边 (参_后缀, 取文本长度 (参_后缀) － 倒找文本 (参_后缀, “.”, , 假) ＋ 1)  ' 带后缀的文件名，取出后缀名

Text_注册表 ＝ 取文本注册项 (#根类, 取文本注册项 (#根类, Text ＋ “\”, ) ＋ “\DefaultIcon\”, )  ' C:\Windows\system32\imageres.dll,-102

' 输出调试文本 (Text_注册表)

局_Path ＝ 取文本左边 (Text_注册表, 倒找文本 (Text_注册表, “,”, , 假) － 1)

局_索引 ＝ 到整数 (取文本右边 (Text_注册表, 取文本长度 (Text_注册表) － 倒找文本 (Text_注册表, “,”, , 假)))

a ＝ ExtractIconEx (局_Path, 局_索引, hIco32, hIco16, 1)

.如果真 (a ＝ -1)  ' 是否失败

    .判断开始 (Text ＝ “.exe”)

        返回 (#exe)

    .默认

        返回 (#空)

    .判断结束

.如果真结束

.判断开始 (是否为空 (是否小图标))

    返回 (转换图标_从句柄 (hIco32, 假))

.默认

    返回 (转换图标_从句柄 (hIco16, 假))

.判断结束