.版本 2
.支持库 iext
.程序集变量 Wifi, WiFi无线网络类
.子程序 __启动窗口_创建完毕
Checkfocus ()
多线程_启动线程 (&EnumAdapters)
多线程_启动线程 (&Addlist)
.子程序 EnumAdapters
.局部变量 Number
.局部变量 i
.局部变量 name, 文本型
组合框1.清空 ()
Number ＝ Wifi.取网卡数量 ()
.如果真 (Number ＝ 0)
返回 ()
.如果真结束
.计次循环首 (Number, i)
组合框1.加入项目 (Wifi.取网卡名称 (i), )
.计次循环尾 ()
组合框1.现行选中项 ＝ 0
GetAvailableNetworkList ()
EnumProfileList ()
.子程序 Checkfocus
编辑框_SSID.内容 ＝ Wifi.取热点用户名 ()
编辑框_Pw.内容 ＝ Wifi.取热点密码 ()
.如果 (Wifi.是否开启热点 ())
按钮_start.禁止 ＝ 真
按钮_close.禁止 ＝ 假
.否则
按钮_close.禁止 ＝ 真
.如果结束
.子程序 Addlist
.局部变量 Number
.局部变量 i
.局部变量 list, 网卡数据类型, , "0"
.局部变量 name, 文本型
组合框2.清空 ()
Number ＝ 网卡_枚举2 (list)
name ＝ 网卡_取共享网卡 ()
.计次循环首 (Number, i)
组合框2.加入项目 (list [i].Name, )
.如果 (list [i].Name ＝ name)
组合框2.现行选中项 ＝ i
.否则
组合框2.现行选中项 ＝ 0
.如果结束
处理事件 ()
.计次循环尾 ()
.子程序 GetAvailableNetworkList
.局部变量 Number
.局部变量 i
.局部变量 wxwl, 无线网络列表_, , "0"
.局部变量 index
超级列表框1.全部删除 ()
Number ＝ Wifi.取可见网络列表 (, wxwl)
.计次循环首 (Number, i)
.如果真 (超级列表框1.查找表项 (wxwl [i].SSID, 0, 真, 0) ＝ -1)
index ＝ 超级列表框1.插入表项 (, , , , , )
超级列表框1.置标题 (index, 0, wxwl [i].SSID)
超级列表框1.置标题 (index, 1, 到文本 (wxwl [i].信号质量))
超级列表框1.置标题 (index, 2, wxwl [i].安全类型)
超级列表框1.置标题 (index, 3, wxwl [i].加密类型)
超级列表框1.置标题 (index, 4, 选择 (wxwl [i].是否可连接, “真”, “假”))
超级列表框1.置标题 (index, 5, wxwl [i].无线电类型)
超级列表框1.置标题 (index, 6, wxwl [i].RSSI指示触发值)
.如果真结束
处理事件 ()
.计次循环尾 ()
超级列表框1.现行选中项 ＝ 0
超级列表框1.获取焦点 ()
.子程序 _按钮1_被单击
.如果真 (Wifi.刷新网络 ())
GetAvailableNetworkList ()
.如果真结束
.子程序 EnumProfileList
.局部变量 Number
.局部变量 i
.局部变量 profile, 无线配置文件信息_, , "0"
列表框1.清空 ()
Number ＝ Wifi.枚举配置文件 (, profile)
.如果真 (Number ＝ 0)
返回 ()
.如果真结束
.计次循环首 (Number, i)
列表框1.插入项目 (0, profile [i].配置文件名, )
.计次循环尾 ()
.子程序 _按钮2_被单击
.局部变量 profilename, 文本型
.局部变量 index
index ＝ 列表框1.现行选中项
.如果真 (index ＝ -1)
返回 ()
.如果真结束
profilename ＝ 列表框1.取项目文本 (index)
Profile ＝ Wifi.取配置文件 (, profilename)
.如果真 (取文本长度 (Profile) ＞ 2)
载入 (窗口1, , 真)
.如果真结束
.子程序 _按钮3_被单击
.局部变量 oldName, 文本型
.局部变量 NweName, 文本型
.局部变量 index
index ＝ 列表框1.现行选中项
.如果真 (index ＝ -1)
返回 ()
.如果真结束
oldName ＝ 列表框1.取项目文本 (index)
.如果真 (输入框 (“请输入新的配置文件名称”, , , NweName, #输入文本))
.如果真 (Wifi.重命名配置文件 (, oldName, NweName))
列表框1.置项目文本 (index, NweName)
.如果真结束
.如果真结束
.子程序 _按钮4_被单击
.局部变量 index
.局部变量 oldName, 文本型
index ＝ 列表框1.现行选中项
.如果真 (index ＝ -1)
返回 ()
.如果真结束
oldName ＝ 列表框1.取项目文本 (index)
.如果真 (Wifi.配置文件排序 (, oldName, index － 1))
EnumProfileList ()
.如果真结束
.子程序 _按钮5_被单击
.局部变量 index
.局部变量 oldName, 文本型
index ＝ 列表框1.现行选中项
.如果真 (index ＝ -1)
返回 ()
.如果真结束
oldName ＝ 列表框1.取项目文本 (index)
.如果真 (Wifi.配置文件排序 (, oldName, index ＋ 1))
EnumProfileList ()
.如果真结束
.子程序 _按钮6_被单击
.局部变量 index
.局部变量 oldName, 文本型
index ＝ 列表框1.现行选中项
.如果真 (index ＝ -1)
返回 ()
.如果真结束
oldName ＝ 列表框1.取项目文本 (index)
.如果真 (Wifi.删除配置文件 (, oldName))
列表框1.删除项目 (index)
.如果真结束
.子程序 _超级列表框1_检查框状态被改变
.参数 表项索引, 整数型
.参数 检查框状态, 整数型
.局部变量 Number
.局部变量 i
Number ＝ 超级列表框1.取表项数 ()
.变量循环首 (0, Number － 1, 1, i)
超级列表框1.置状态图片 (i, 0)
.变量循环尾 ()
超级列表框1.置状态图片 (表项索引, 1)
超级列表框1.选择表项 (表项索引)
.子程序 _超级列表框1_当前表项被改变
.局部变量 Number
.局部变量 i
.局部变量 index
index ＝ 超级列表框1.现行选中项
Number ＝ 超级列表框1.取表项数 ()
.变量循环首 (0, Number － 1, 1, i)
超级列表框1.置状态图片 (i, 0)
.变量循环尾 ()
超级列表框1.置状态图片 (index, 1)
.子程序 _按钮_连接_被单击
.局部变量 Number
.局部变量 i
.局部变量 name, 文本型
Number ＝ 超级列表框1.取表项数 ()
.变量循环首 (0, Number － 1, 1, i)
.如果真 (超级列表框1.取当前状态图片 (i) ＝ 1)
SSID ＝ 超级列表框1.取标题 (i, )
跳出循环 ()
.如果真结束
处理事件 ()
.变量循环尾 ()
name ＝ 超级列表框1.取标题 (i, 2)
.判断开始 (name ＝ “WPA2-个人”)
authentication ＝ “WPA2PSK”
.判断 (name ＝ “WPA-个人”)
authentication ＝ “WPAPSK”
.默认
.判断结束
encryption ＝ 超级列表框1.取标题 (i, 3)
载入 (窗口_Password, , 真)
.子程序 _按钮_断开_被单击
.如果真 (Wifi.断开网络 ())
按钮_断开.禁止 ＝ 真
按钮_连接.禁止 ＝ 假
.如果真结束
.子程序 _按钮_start_被单击
Wifi.一键共享 (编辑框_SSID.内容, 编辑框_Pw.内容, 组合框2.内容)
.如果真 (Wifi.是否开启热点 ())
按钮_start.禁止 ＝ 真
按钮_close.禁止 ＝ 假
.如果真结束
.子程序 _按钮_close_被单击
Wifi.一键取消 ()
.如果真 (Wifi.是否开启热点 () ＝ 假)
按钮_start.禁止 ＝ 假
按钮_close.禁止 ＝ 真
.如果真结束