.版本 2
.支持库 spec
.程序集 窗口程序集1
.子程序 __启动窗口_创建完毕
标题 = “易语言注册表操作详解”
.子程序 _按钮_学习建立注册表的项并读出_被单击, , , 学习建立注册表的“项”
.局部变量 a, 逻辑型
' 目标:在HKEY_CURRENT_USER这个根键下建立"我爱精益论坛"这个“项”
a = 写注册项 (#现行用户, “我爱精易论坛\”, “不得不写”)
' 在注册表中新建一个"项后,它下面会自动产生一个"默认字符串值(REG_SZ)"的“键”,值为未设置。
' 因为"写注册项"库命令的参数"欲写入值"不能接受空数据,即第3个参数不能为空。
' 所以我不得不在第3个参数处写点东西,
' 即修改“我爱精易论坛”这个项下的"默认字符串值(REG_SZ)"这个“键”的值。
.如果真 (a)
信息框 (“写注册项成功!”, 0, )
调试输出 (取文本注册项 (#现行用户, “我爱精易论坛\”, ))
' 想取一下HKEY_CURRENT_USER下有没有“我爱精易论坛”这个项
' 但由于命令功能的限制,所以我只能取“我爱精易论坛”这个项下,
' "默认字符串值(REG_SZ)"这个“键”的值
.如果真结束
.子程序 _按钮_学习建立字符串型键并读出_被单击
.局部变量 a, 逻辑型
' 在"KEY_CURRENT_USER\我爱精益论坛"这个"项"下建立名为"普通字符串",
' 类型为REG_SZ,值为"我爱易语言"的1个"键",并"调试输出"检查建立了没有。
a = 写注册项 (#现行用户, “我爱精易论坛\普通字符串”, “我爱易语言”)
' “普通字符串”是REG_SZ型“键”名, “我爱易语言”是“键”值。
.如果真 (a)
信息框 (“写注册项成功!”, 0, )
调试输出 (取文本注册项 (#现行用户, “我爱精易论坛\普通字符串”, ))
' 取一下“HKEY_CURRENT_USER\我爱精易论坛”下名为“普通字符串”,
' 类型为REG_SZ的“键”的值,并输出以便观看。
.如果真结束
.子程序 _按钮_学习建立整数型键并读出_被单击
.局部变量 a, 逻辑型
' 在"KEY_CURRENT_USER\我爱精益论坛"这个"项"下建立名为"整数型键",
' 类型为REG_DWORD,值为"999"的1个"键",并"调试输出"检查建立了没有。
a = 写注册项 (#现行用户, “我爱精易论坛\整数型键”, 999)
' “整数型键”是REG_DWORD型“键”名, “999”是“键”值。
.如果真 (a)
信息框 (“写注册项成功!”, 0, )
调试输出 (取数值注册项 (#现行用户, “我爱精易论坛\整数型键”, ))
' 取一下“HKEY_CURRENT_USER\我爱精易论坛”下名为“整数型键”,
' 类型为REG_DWORD的“键”的值,并输出以便观看。
.如果真结束
.子程序 _按钮_学习建立字节集型键并读出_被单击
.局部变量 a, 逻辑型
' 在"KEY_CURRENT_USER\我爱精益论坛"这个"项"下建立名为"字节集型键",
' 类型为REG_BINARY,值为"{ 03,04, 233, 210 }"的1个"键",并"调试输出"检查建立了没有。
a = 写注册项 (#现行用户, “我爱精易论坛\字节集型键”, { 3, 4, 122, 12 })
' “字节集型键”是REG_BINARY型“键”名, “{ 03,04, 122, 12 }”是“键”值。
.如果真 (a)
信息框 (“写注册项成功!”, 0, )
调试输出 (取字节集注册项 (#现行用户, “我爱精易论坛\字节集型键”, ))
' 取一下“HKEY_CURRENT_USER\我爱精易论坛”下名为“字节集型键”,
' 类型为REG_BINARY的“键”的值,并输出以便观看。
.如果真结束
.子程序 _按钮_注册表项的检查_被单击
.局部变量 a, 逻辑型
' 在注册表中新建一个"项后,它下面会自动产生一个"默认字符串值(REG_SZ)"的“键”,值为未设置。
' 那么检查"默认字符串值(REG_SZ)"的“键”是否存在即可。返回真就说明存在。
a = 注册项是否存在 (#现行用户, “我爱精易论坛\”)
.如果真 (a)
信息框 (“找到了!”, 0, )
.如果真结束
.子程序 _按钮_注册表键的检查_被单击
.局部变量 a, 逻辑型
' 检查"HKEY_CURRENT_USER\我爱精益论坛"下有没有"普通字符串"这个键
a = 注册项是否存在 (#现行用户, “我爱精易论坛\普通字符串”)
.如果真 (a)
信息框 (“找到了!”, 0, )
.如果真结束
.子程序 _按钮_注册表键的删除_被单击
.局部变量 a, 逻辑型
' 删除"HKEY_CURRENT_USER\我爱精益论坛"下"普通字符串"这个“键”
a = 删除注册项 (#现行用户, “我爱精易论坛\普通字符串”)
.如果真 (a)
信息框 (“删除成功!”, 0, )
.如果真结束
' 删除"HKEY_CURRENT_USER\我爱精益论坛"下"默认字符串"这个“键”
a = 删除注册项 (#现行用户, “我爱精易论坛\”)
.如果真 (a)
信息框 (“删除成功!”, 0, )
.如果真结束
.子程序 _按钮_注册表项的删除_被单击
.局部变量 a, 逻辑型
' 删除"HKEY_CURRENT_USER"下"我爱精益论坛"这个“项”
a = 删除注册项 (#现行用户, “我爱精易论坛”)
.如果真 (a)
信息框 (“删除成功!”, 0, )
.如果真结束